ZSHOW may specify an unsubscripted or subscripted global or local variable name (glvn) into which ZSHOW places its output. If the argument does not include a global or local variable name, ZSHOW directs its output to the current device.

When ZSHOW directs its output to a variable, it adds two levels of descendants to that variable. The first level subscript contains a one-character string from the set of upper-case ZSHOW action codes, identifying the type of information. ZSHOW implicitly KILLs all descendants of the first level nodes. ZSHOW stores information elements at the second level using ascending integers, starting at 1.

When a ZSHOW "V" directs its output to a local variable (lvn), the result does not contain a copy of the descendants of the resulting "V" node.

Example:

    GTM>KILL ZSHOW "s":a ZWRITE
    a("S",1)="+1^GTM$DMOD (Direct Mode) "
    GTM>
    

This ZSHOW stores the base level M/DIRECT stack in the local variable a.

Example:

    GTM>KILL SET b(1,"two")="test" ZSHOW "v":a ZWR
    a("V",1)="b(1,""two"")=""test"""
    b(1,"two")="test"
    GTM>
    

This ZSHOW stores all local variables in the local variable a. Note that ZSHOW does not replicate a("V") and a("V",1).

Example:

    GTM>KILL SET a(1,"D",3,5)="stuff",a(1,"X",2)="",a(1)=1 
    
    GTM>ZSH "d":a(1)
    GTM>ZWRITE
    a(1)=1
    a(1,"D",1)="_TNA7341: OPEN TERMINAL EDIT NOESCA HOST IN NOPAST NOREADS TTSY TYPE WIDTH=80 LENG=24"
    a(1,"X",2)=""
    
    
    GTM>
    

This ZSHOW stores the current open device information under a(1). Notice how the ZSHOW deletes a(1,"D",3,5).

Example:

    GTM>KILL ^ZSHOW
    GTM>ZB -*,lab^rout ZSH "B":^ZSHOW
    GTM>ZWRITE ^ZSHOW
    ^ZSHOW("B",1)="LAB^ROUT"
    GTM>        
    

This ZSHOW stores the current ZBREAK information under the global variable ^ZSHOW.